Apple Reference & Present…ry 5: (Reseller Edition)/Apple Reference & Presentations Library 5.0 (Reseller Edition).iso/3-Presentations/Apple Demos/Training/Macintosh SE⁄30 Training/Apple Macintosh SE⁄30/Apple Macintosh SE_30/stack.txt

Text File | 1990-03-19 | 10KB | 244 lines

-- stack: in
-- format: 8 (HyperCard 1)
-- flags: 0x1000 (none)
-- protect password hash: 0
-- maximum user level: 5 (scripting)
-- window: Rect(x1=0, y1=0, x2=0, y2=0)
-- screen: Rect(x1=0, y1=0, x2=0, y2=0)
-- card dimensions: w=0 h=0
-- scroll: x=0 y=0
-- background count: 15
-- first background id: 3987
-- card count: 239
-- first card id: 9977
-- list block id: 129741
-- print block id: 3387
-- font table block id: 0
-- style table block id: 0
-- free block count: 2
-- free size: 9504 bytes
-- total size: 598016 bytes
-- stack block size: 6656 bytes
-- created by hypercard version: 0x01208000
-- compacted by hypercard version: 0x01228000
-- modified by hypercard version: 0x01228000
-- opened by hypercard version: 0x01228000
-- patterns[0]: 0x0000000000000000
-- patterns[1]: 0x8000000008000000
-- patterns[2]: 0x8800220088002200
-- patterns[3]: 0x8888222288882222
-- patterns[4]: 0x88AA22AA88AA22AA
-- patterns[5]: 0xCCAA33AACCAA33AA
-- patterns[6]: 0xEEAABBAAEEAABBAA
-- patterns[7]: 0xEEBBBBEEEEBBBBEE
-- patterns[8]: 0xFFBBFFEEFFBBFFEE
-- patterns[9]: 0xFFBBFFFFFFBBFFFF
-- patterns[10]: 0x8010022001084004
-- patterns[11]: 0xFFFFFFFFFFFFFFFF
-- patterns[12]: 0x8822882288228822
-- patterns[13]: 0x1122448811224488
-- patterns[14]: 0xC4800C6843023026
-- patterns[15]: 0xB130031BD8C00C8D
-- patterns[16]: 0xAA00AA00AA00AA00
-- patterns[17]: 0xEEEAEE00EEAEEE00
-- patterns[18]: 0x8855225588552255
-- patterns[19]: 0x77DD77DD77DD77DD
-- patterns[20]: 0x8000000000000000
-- patterns[21]: 0xAA55AA55AA55AA55
-- patterns[22]: 0xFF888888FF888888
-- patterns[23]: 0x0800220080002200
-- patterns[24]: 0x0814224180412214
-- patterns[25]: 0x8000080080000800
-- patterns[26]: 0xCCCC3333CCCC3333
-- patterns[27]: 0x8888888888888888
-- patterns[28]: 0x8844221188442211
-- patterns[29]: 0xAA550000AA550000
-- patterns[30]: 0x40A00000040A0000
-- patterns[31]: 0x8040200002040800
-- patterns[32]: 0xAA00800080008000
-- patterns[33]: 0xFF808080FF808080
-- patterns[34]: 0xFF00FF00FF00FF00
-- patterns[35]: 0xFF808080FF080808
-- patterns[36]: 0xAA00800080008000
-- patterns[37]: 0xAAAAAAAAAAAAAAAA
-- patterns[38]: 0xFF80808080808080
-- patterns[39]: 0xF0F0F0F00F0F0F0F
-- checksum: 0x0
----- HyperTalk script -----
--————————————————————————————————————————————————————————————————————
--  Stack created for Apple Computer, Inc.
--  Copyright © 1988 by Apple Computer, Inc.
--  HyperCard construction — Chuck Walker.
--  PopUpMenu XFCN by Andrew Gilmartin, Brown University
--————————————————————————————————————————————————————————————————————
--  Begin Stack Script  ——————————————————————————————————————————————
--————————————————————————————————————————————————————————————————————
on openStack

  if the version < 1.2 then
    answer "This stack requires HyperCard version 1.2." with "Continue" or "Home"
    if it is "Home" then domenu home
  end if

  put item 2 of the screenRect into screenTop
  if top of card window < screenTop + 20 then hide menuBar
  hide tool window
  hide pattern window
  hide msg
  resetMap

end openStack
--————————————————————————————————————————————————————————————————————
on closeStack

  answer "Do you want to save your place?" with "Yes" or "No"
  if it is "No" then put empty into field "footprints" of card "Map"
  pass closeStack

end closeStack
--————————————————————————————————————————————————————————————————————
--  intercept keyboard handlers:  ————————————————————————————————————
--————————————————————————————————————————————————————————————————————
--  same as clicking the arrow buttons  ——————————————————————————————

on arrowKey whatKey

  if whatKey = "Left" then click at 442,328
  if whatKey = "Right" then click at 469,328

end arrowKey

--  same as clicking the return button  ——————————————————————————————

on returnKey

  click at 498,328

end returnKey

--  intercept enter key  —————————————————————————————————————————————

on enterKey
end enterKey

--————————————————————————————————————————————————————————————————————
--  offer help to the lost  ——————————————————————————————————————————

on mouseUp
  global clickTime
  if the ticks - clickTime < 50 then exit mouseUp

  answer "Click one of the Arrow buttons." with "Help" or "OK"
  if it is "Help" then
    push card
    visual dissolve
    go card "howToUse"
  else exit mouseUp

end mouseUp
--————————————————————————————————————————————————————————————————————
-- disable certain menu options which are not appropriate  ———————————


on domenu menu                       --// Added by Medior, Inc. 2/20/90
  global RPStackName
  if menu is in "Home,Quit HyperCard" and RPStackName is not empty then
    set cursor to watch
    put RPStackName into shortname
    repeat until offset(":",shortname) = 0
      delete char 1 to offset(":",shortname) of shortname
    end repeat
    delete last char of shortname
    answer "This will return to "&shortname&"." with "Cancel" or "OK"
    if it is "Cancel" then exit domenu
    set cursor to watch
    lock screen
    go RPStackName
    unlock screen with dissolve
    exit domenu
  else if Menu is in "Message Find... Print Report... Last Prev Next" then
  else pass doMenu
end domenu

--————————————————————————————————————————————————————————————————————
-- popUp table of contents menu  —————————————————————————————————————

on mainMenu
  global clickTime, checkedItem

  get the loc of card window
  put item 1 of it into LeftWind
  put item 2 of it into TopWind
  get the rect of target
  put item 1 of it into leftSide
  put item 4 of it into bottomSide
  put (TopWind + bottomSide +(checkedItem * 16) - 16) into hMenuLoc
  put LeftWind + leftSide + 1 into vMenuLoc

  get PopUpMenu(field "menuList" of card "Map", checkedItem, hMenuLoc, vMenuLoc)

  if it = 1 then
    push card
    go card "Map"
  end if
  if it = 2 then
    push card
    go card "howToUse"
  end if
  if it = 4 then go card "content1"
  if it = 5 then go card "content2"
  if it = 6 then go card "content3"
  if it = 7 then go card "content4"
  if it = 8 then go card "content5"
  if it = 9 then go card "content6"
  if it = 10 then go card "content7"
  if it = 11 then go card "content8"
  if it = 13 then
    push card
    go card "content0"
  end if
  if it = 14 then
    push card
    go card "index1"
  end if
  if it = 16 then doMenu "Print Card"

end mainMenu
--————————————————————————————————————————————————————————————————————
--  handler resets map to no footprints  —————————————————————————————

on resetMap
  global mapCleaning

  put "true" into mapCleaning
  lock screen
  push card
  go card "Map"

  repeat with x = 1 to 12
    set the style of bkgnd button x to opaque
  end repeat

  pop card
  put "false" into mapCleaning
  unlock screen

end resetMap
--————————————————————————————————————————————————————————————————————
--  timing for all animation events  —————————————————————————————————

on runningPause

  repeat 250
    if the mouse is down then
      click at the clickloc
      exit to HyperCard
    end if
  end repeat

end runningPause
--————————————————————————————————————————————————————————————————————
--  End Stack Script  ————————————————————————————————————————————————
--————————————————————————————————————————————————————————————————————